Arduino Ethernet Shield Tutorial

The Arduino Ethernet Shield allows you to easily connect your Arduino to the internet. This shield enables your Arduino to send and receive data from anywhere in the world with an internet connection. You can use it to do fun stuff like control robots remotely from a website, or ring a bell every time you get a new twitter message. This shield opens up endless amounts of possibility by allowing you to connect your project to the internet in no-time flat.

Step 1: Setup

Setting it up is as simple as plugging the header pins from the shield into your Arduino.

Note that the Ethernet Shield sold at Radioshack is online compatible with Arduino Uno Rev. 3 boards (or later). It has too many pins to plug into earlier version Arduino boards.

Step 2: Shield Features

The Ethernet Shield is based upon the W51000 chip, which has an internal 16K buffer. It has a connection speed of up to 10/100Mb. This is not the fastest connection around, but is also nothing to turn your nose up at.

It relies on the Arduino Ethernet library, which comes bundled with the development environment.

There is also an on-board micro SD slot which enables you to store a heck-of-a-lot of data, and serve up entire websites using just your Arduino. This requires the use of an external SD library, which does not come bundled with the software. Using the SD card is not covered in this Instructable. However, it is covered in the Step 8 of the Wireless SD card instructable.

The board also has space for the addition of a Power over Ethernet (PoE) module, which allows you to power your Arduino over an Ethernet connection.

For a full technical overview, see the official Ethernet Shield page.

Step 3: Get started

Plug the Arduino into your computer's USB port, and the Ethernet shield into your router (or direct internet connection).

Next, open the Arduino development environment. I highly recommend upgrading to Arduino 1.0 or later (if you have not done so already). This version of the software has built in DHCP support, and does not require manually configuring an IP address.

To figure out what IP address has been assigned to your board, open the DhcpAddressPrinter sketch. This can be found at:

File --> Examples --> Ethernet --> DhcpAddressPrinter

Once open, you may need to change the Mac address. On newer versions of the Ethernet shield, you should see this address on a sticker attached to the board. If you are missing a sticker, simply making up a unique mac address should work. If you are using multiple shields, make sure each has a unique mac address.

Once the mac address is properly configured, upload the sketch to your Arduino, and open the serial monitor. It should print out the IP address in use.

Step 4: Server

You can use the Arduino Ethernet shield as a web server to load an HTML page or function as a chat server. You can also parse requests sent by a client, such as a web browser. The following two examples show how to use it to serve HTML pages, and parse URL strings.

One important thing to keep in mind is that you will have to enter your Arduino's IP address in both of the examples below in order for them to work.

The following code changes the web page served based on a button press:

/*
  Web Server Demo
  thrown together by Randy Sarafan
 
 A simple web server that changes the page that is served, triggered by a button press.
 
 Circuit:
 * Ethernet shield attached to pins 10, 11, 12, 13
 * Connect a button between Pin D2 and 5V
 * Connect a 10K resistor between Pin D2 and ground
 
 Based almost entirely upon Web Server by Tom Igoe and David Mellis
 
 Edit history: 
 created 18 Dec 2009
 by David A. Mellis
 modified 4 Sep 2010
 by Tom Igoe
 
 */

#include <SPI.h>
#include <Ethernet.h>

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = { 0x00, 0xAA, 0xBB, 0xCC, 0xDA, 0x02 };
IPAddress ip(191,11,1,1); //<<< ENTER YOUR IP ADDRESS HERE!!!

// Initialize the Ethernet server library
// with the IP address and port you want to use 
// (port 80 is default for HTTP):
EthernetServer server(80);

int buttonPress = 1;

void setup()
{
  pinMode(2, INPUT);

  // start the Ethernet connection and the server:
  Ethernet.begin(mac, ip);
  server.begin();
}

void loop()
{
  buttonPress = digitalRead(2); 
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println();
          
          //serves a different version of a website depending on whether or not the button
          //connected to pin 2 is pressed.
          if (buttonPress == 1) {
            client.println("<cke:html><cke:body bgcolor=#FFFFFF>LIGHT!</cke:body></cke:html>");
          }
          else if (buttonPress == 0){
            client.println("<cke:html><cke:body bgcolor=#000000 text=#FFFFFF>DARK!</cke:body></cke:html>");
          }
          

          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        } 
        else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
  }
}

To make this example code work, simply attach a button between pin D2 and 5V,  a 10K resistor between pin D2 and ground, and then load the IP address of your Arduino into your web browser. The page should load with a black background. Press and hold the button, and then refresh the browser page. The site should now load with a white background.


The following code lights up an LED depending on the URL that is sent to the Arduino:

/*
  Web Server Demo
  thrown together by Randy Sarafan
 
 Allows you to turn on and off an LED by entering different urls.
 
 To turn it on:
 http://your-IP-address/$1
 
 To turn it off:
 http://your-IP-address/$2
 
 Circuit:
 * Ethernet shield attached to pins 10, 11, 12, 13
 * Connect an LED to pin D2 and put it in series with a 220 ohm resistor to ground
 
 Based almost entirely upon Web Server by Tom Igoe and David Mellis
 
 Edit history: 
 created 18 Dec 2009
 by David A. Mellis
 modified 4 Sep 2010
 by Tom Igoe
 
 */

#include <SPI.h>
#include <Ethernet.h>

boolean incoming = 0;

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = { 0x00, 0xAA, 0xBB, 0xCC, 0xDA, 0x02 };
IPAddress ip(191,11,1,1); //<<< ENTER YOUR IP ADDRESS HERE!!!

// Initialize the Ethernet server library
// with the IP address and port you want to use 
// (port 80 is default for HTTP):
EthernetServer server(80);

void setup()
{
  pinMode(2, OUTPUT);

  // start the Ethernet connection and the server:
  Ethernet.begin(mac, ip);
  server.begin();
  Serial.begin(9600);
}

void loop()
{
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        
        //reads URL string from $ to first blank space
        if(incoming && c == ' '){ 
          incoming = 0;
        }
        if(c == '$'){ 
          incoming = 1; 
        }
        
        //Checks for the URL string $1 or $2
        if(incoming == 1){
          Serial.println(c);
          
          if(c == '1'){
            Serial.println("ON");
            digitalWrite(2, HIGH);
          }
          if(c == '2'){
            Serial.println("OFF");
            digitalWrite(2, LOW);
          }
        
        }

        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        } 
        else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
  }
}

To make this work connect the positive lead an LED to pin D2, and the negative lead in series with a 220 ohm resistor to ground.

To turn on the LED enter this into your browser:
http://[YOUR IP ADDRESS HERE]/$1

To turn off the LED enter this into your browser:
http://[YOUR IP ADDRESS HERE]/$2

Note: You should obviously replace [YOUR IP ADDRESS HERE] with your IP address.

Step 5: Client

You can also use the Ethernet Shield as a client. In other words, you can use it to read websites like a web browser.

Websites have a lot of text both visible and hidden, which makes programming on the client side very tricky. Reading information from websites typically involves parsing a lot of strings. This is maddening, but worth it, if that is what you intend to do.

I was going to write some code to read Twitter messages, but such a code already exists as an example within the Arduino programmer. Instead, I simply modified it slightly to turn on an LED if a special message is read.

To make this work connect the positive lead an LED to pin D2, and the negative lead in series with a 220 ohm resistor to ground.

Don't forget to enter your own IP address into the code below, or it will not work.

Here is the code:

/*
  Twitter Client with Strings
 
 This sketch connects to Twitter using an Ethernet shield. It parses the XML
 returned, and looks for <text>this is a tweet</text>
 
 You can use the Arduino Ethernet shield, or the Adafruit Ethernet shield, 
 either one will work, as long as it's got a Wiznet Ethernet module on board.
 
 This example uses the DHCP routines in the Ethernet library which is part of the 
 Arduino core from version 1.0 beta 1
 
 This example uses the String library, which is part of the Arduino core from
 version 0019.  
 
 Circuit:
  * Ethernet shield attached to pins 10, 11, 12, 13
 
 created 21 May 2011
 by Tom Igoe
 
 This code is in the public domain.
 
 */
#include <SPI.h>
#include <Ethernet.h>


// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = { 
  0x00, 0xAA, 0xBB, 0xCC, 0xDE, 0x01 };
IPAddress ip(191,11,1,1); //<<< ENTER YOUR IP ADDRESS HERE!!!

// initialize the library instance:
EthernetClient client;

const int requestInterval = 60000;  // delay between requests

char serverName[] = "api.twitter.com";  // twitter URL

boolean requested;                   // whether you've made a request since connecting
long lastAttemptTime = 0;            // last time you connected to the server, in milliseconds

String currentLine = "";            // string to hold the text from server
String tweet = "";                  // string to hold the tweet
boolean readingTweet = false;       // if you're currently reading the tweet

void setup() {
  
  pinMode(2, OUTPUT);
  
  // reserve space for the strings:
  currentLine.reserve(256);
  tweet.reserve(150);

// initialize serial:
  Serial.begin(9600);
  // attempt a DHCP connection:
  if (!Ethernet.begin(mac)) {
    // if DHCP fails, start with a hard-coded address:
    Ethernet.begin(mac, ip);
  }
  // connect to Twitter:
  connectToServer();
}



void loop()
{
  if (client.connected()) {
    if (client.available()) {
      // read incoming bytes:
      char inChar = client.read();

      // add incoming byte to end of line:
      currentLine += inChar; 

      // if you get a newline, clear the line:
      if (inChar == '\n') {
        currentLine = "";
      } 
      // if the current line ends with <text>, it will
      // be followed by the tweet:
      if ( currentLine.endsWith("<text>")) {
        // tweet is beginning. Clear the tweet string:
        readingTweet = true; 
        tweet = "";
      }
      // if you're currently reading the bytes of a tweet,
      // add them to the tweet String:
      if (readingTweet) {
        if (inChar != '<') {
          tweet += inChar;
        } 
        else {
          // if you got a "<" character,
          // you've reached the end of the tweet:
          readingTweet = false;
          Serial.println(tweet);
          
          if(tweet == ">Hello Cruel World"){
           digitalWrite(2, HIGH);
           Serial.println("LED ON!");
          }
          if(tweet != ">Hello Cruel World"){
           digitalWrite(2, LOW);
           Serial.println("LED OFF!");
          }
          
          // close the connection to the server:
          client.stop(); 
        }
      }
    }   
  }
  else if (millis() - lastAttemptTime > requestInterval) {
    // if you're not connected, and two minutes have passed since
    // your last connection, then attempt to connect again:
    connectToServer();
  }
}

void connectToServer() {
  // attempt to connect, and wait a millisecond:
  Serial.println("connecting to server...");
  if (client.connect(serverName, 80)) {
    Serial.println("making HTTP request...");
  // make HTTP GET request to twitter:
    client.println("GET /1/statuses/user_timeline.xml?screen_name=RandyMcTester&count=1 HTTP/1.1");
    client.println("HOST: api.twitter.com");
    client.println();
  }
  // note the time of this connect attempt:
  lastAttemptTime = millis();
}   

Presumably you are going to want to read something other than the recent post on the RandyMcTester Twitter feed.

To read other Twitter feeds, change the following bit of text:
client.println("GET /1/statuses/user_timeline.xml?screen_name=[NEW TWITTER NAME HERE]&count=1 HTTP/1.1");

Comments

[sandeep200870]

hi, i have successfully sent commands from a browser to ethernet shield in same network. but, can u please tell me how to do same if i have to do it from a separate network? actually i want to make an android app to operate ethernet shield, so i need it necessarily.

[mwezel]

your ethernet shields is dead you plug something wrong

[parth_bhat]

my ethernet shields ic gets hot will u plsplspls help me for that
am using arduino leonardo board
pls help me

regards
pyt

[randofo]

Did you do anything to change it, and/or did you plug it in correctly? It sounds like you are shorting something.

[sshapiro2]

SOLUTION:

sorry i had the wrong resistors in the circuit, was using those baby blue ones, I find them hard to read. make sure its the right resistor!

[sshapiro2]

Thanks!

Any advice: i have confirmed ip address with addressprinter.

byte mac[] = { 0x90, 0xA2, 0xDA, 0x0D, 0x56, 0xC6 };
IPAddress ip(10,0,0,10); //<<< ENTER YOUR IP ADDRESS HERE!!!

The light goes on when i uplaod the script but wont respond to the ip $1 or $2, the page just sits and doesnt load. i even tried the script below to return a black screen and nothing loads on that ip.

Thanks!

[sshapiro2]

i have a similar problem with the Switch activated code. It loads a white page with the words DARk but nothing happens when the switch is pressed, tried refreshing etc

[lazer eyes]

hai I have ethernet w5100 shield v3 and I have UNO and I'm using 1.0 and I tried all latest version of ide but i can't able to configure my ip address it is showing error "failed to configure mac address, I have mac address on the sticker , but it doesn't work
1) i hooked the SHIELD with uno
2) I changed the mac address in chcp address printer
3) program uploaded,
4) rj45 hooked with shield

after that my system showed local area network connected ,

when i click the serial monitor its showing only failed to confogure mac address"

what shall i do

[clsorens]

I know it's kinda old-ish post, but just in case anyone else is still having this problem like I was too here's a solution.

It should still turn the light on, but the reason it's not displaying a web page is because the code doesn't return a web page.

change the "
if(c == '\n')
{
currentLineIsBlank = true;
} " to "

if (c == '\n' && currentLineIsBlank)
{
// send a standard http response header
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println("Connnection: close");
client.println();
client.println("");
client.println("");
client.println("");
client.println("");
currentLineIsBlank = true;
break;
}

"

This code will return a web page with the background set to black (#000000) after light turns on.

[Zarainia]

Is the "serverName" line supposed to be changed?

[Zarainia]

Never mind, it worked. Thanks for the tutorial!

[crusso]

Great instructable, Thank you very much!

[grandleo75]

Awesome tutorial. Thanks for posting it.

I seem to have a problem. pin2 seems to default to on. How can I get ti to default to off?

Thanks,

[MegaPicklesrock]

Never mind. I went to arduino 1.0.1 and it worked!

[MegaPicklesrock]

When I upload my code to my arduino it says "IPAddress does not name a type" Can you guys help. I tried fixing it but it always fails

[waterlubber]

What if you don't have access to a router? (e.g apartment building, hotel rooms...) Can I use the ethernet port on my win7 computer?

[purpulhaze]

Port should handle the cross over internally if its a newer computer if it doesn't you will need a cross over cable.

[waterlubber]

What is a crossover cable, and do I need one? (If so, why) I have an Atheros AR8132 PCI-E Fast Ethernet Controller and and Atheros AR5B95 Wireless Network Controller.

[purpulhaze]

Well communicating from pc to pc via the rj45 port in the past you would need a cross over cable. Alot of ports on newer computers usually handle this internally. You may need to check the specs for your computer. Please read up on cross over cables. Just look up pc to pc networking via rj45 port. Basically pc to pc networking. The arduino and ethernet shield is basically a computer.

[waterlubber]

OK, my memory just gave me the memory of hooking up mine with another (it worked) so a Windows 7 computer seems to be compatible. ;P Is it like the serial cables when you have to "cross over" the TX and RX wires? Anyhows, its working. Thanks for the help.

[red_green]

I have an Ethernet shield, and I lost the sticker. All the sketches I upload, however, won't compile. First, is there a way to find the MAC address, and second, do you have any idea why the sample code won't compile?

[waterlubber]

Can I see the code? Also, try making up a random MAC address. How 'bout AB-CA-BA-12-34-AF?

[mcktimo]

Everything worked but when I stressed the server a little by accessing it from multiple browsers (phone, laptop, etc) it would stop responding an need a reset. I wonder why?

[waterlubber]

You might have overloaded the buffer.

[jstelmack]

Just getting started with Audrino and Ethernet Shield. Your tutorial has helped TREMENDOUSLY! Thanks For your time/efforts!

[DNMEBOY]

I have the radioshack ethernet/Sd shield and I can say that it does work with the original arduino uno. Even though the shield has extra pins it still connects to my uno and functions properly. Im not an advanced arduino user but I have not run into anything that requires those extra pins. They just hang over and are not in the way of anything. They can be slightly bent if the caps on the side of the arduino uno are in the way.

[ananth raj]

Can u make a video of this turorial, with connecting to routers and configurations in ethernet shiled.

[randofo]

That is not on my to-do list. Maybe try asking for help in the forums.

[varuninnz]

hey man I want to confirm one thing before buying this shield. Please reply ASAP thanks.
Can this shield be used to send an email without connecting the arduino to a pc?

[willpow1993]

Try http://www.pushingbox.com :) It's an internet based client that, when a specific command is sent from the arduino, will send an email or a phone notification as you specify! I've found it really easy to use and they provide some fairly well documented demo code so you can easily understand what to do and modify it to your own needs. Have fun!

[varuninnz]

thanks man. I'll check it out..

[randofo]

No. It cannot directly send email. You might be able it to connect to a server that sends email on its behalf.

[varuninnz]

okay i'll do my research on that, but i reallly need a client that i can put on the arduino or something that can send emails without a pc. with only the Arduino.

Please let me know if you come across anything..

[randofo]

Try using the Raspberry Pi.

[varuninnz]

okay one lasLAST question. I've used softwares like processing and gobetwino. Done all the examples on gobetwino, so i know that it can be used for sending emails. But I am avoiding using gobetwino, because I've gota real time graph running on processing and it also saves all my values on excel for personal customer analysis later on.

basically Im planning on using a keypad attached to my device to get values inputted from the user and then the calculations from the user inputted values are then displayed on a lcd.

Now my lecturer has allowed me to use a Xigbee shield for wireless data transfer. And also I've seen tutorials on this that claim to send tweets without using any Ethernet shield, however the arduino for those projects are connected to a pc. I've done the tutorials those and my program does compile but none of them have displayed anything on twitter yet.

My question is do you think it might be possible to send an email/twitter via processing if I can send all the data from my device via the Xigbee shield?

ONCE AGAIN THANK YOU FOR SUCH QUICK REPLIES. I REALLY APPRECIATE YOUR ADVISE.

[randofo]

I am not certain. It seems plausible.

[stuarthooper]

Is there a demonstration of a library that reads as well as tweets?

Example:

Tweet sent from phone> Tweet read by Arduino> Turn Motor on for 10 seconds> Tweet sent from Arduino> Tweet read by phone> I'm happy that the motor turned on for ten seconds.

Ideally if this could respond when it is tweeted directly from certain accounts it would work better.

Thanks and Nice Tutorial

[tigerbomb8]

a tutorial that explains how to post to twitter would be nice

[simond]

You can be tweeting in 5 mins with this handy tool:

http://community.thingspeak.com/tutorials/arduino/update-twitter-with-thingtweet-and-arduino-ethernet-shield/

There are probably 101 other ways to do the same thing.

[timbuckles]

simond - would you be willing to help me use thingspeak? i am brand new to all of this and am having a bit of an issue. let me know. thank you.