Twitter Enabled Text to Speech

Let the world know what you're eating for breakfast with an 80's style vocal synthesizer!  This project uses an Arduino to send your Twitter stream to a voice generator chip called the SpeakJet.  The setup that I use here can also be extended to other applications where you'd want to translate text into speech, some ideas:

-a robot which announces things or responds to its environment by speaking
-some kind of assitive technology for the deaf or handicapped
-at the very least, it's a fun alternative to using the serial monitor to print data from the Arduino

In this setup the Arduino requests and receives information from Twitter via an Ethernet shield, which is directly plugged into a router (the USB connection shown in the picture is being used solely for power, not data transmission).  An intermediary chip called the TTS256 translates serial text data from the Arduino into a series of allophones to send to the SpeakJet.  The output from the SpeakJet is sent to an amplifier and then to a small speaker.

A demo of the SpeakJet's voice can be found here.

Parts List:

(x1) SpeakJet IC Sparkfun COM-09578
(x1) Text to Speech chip for SpeakJet - TTS256 Sparkfun COM-09811
(x1) Arduino Uno Sparkfun DEV-11021
(x1) Arduino Ethernet Shield Sparkfun DEV-09026
(x1) 8ohm Speaker Sparkfun COM-09151

(x1) LM386 Amplifier Digikey LM386N-1/NOPB-ND
(x1) 0.047uF ceramic capacitor Digikey P4307-ND
(x1) 220uF electrolytic capacitor Digikey P15322CT-ND
(x1) 10ohm resistor Digikey CF14JT10R0CT-ND
(x1) 10kOhm potentiometer, linear taper Digikey 987-1308-ND
(x1) LED Digikey 365-1175-ND
(x1) 220ohm resistor Digikey CF14JT220RCT-ND
(x2) 10kOhm resistor Digikey CF14JT10K0CT-ND

Other Materials:

Jumper wire
Solder
USB cable
Ethernet cable
breadboard

Step 1: Wire up the SpeakJet with Arduino

I wired up the SpeakJet similarly to how it is wired in Sparkfun's Arduino shield for the SpeakJet called the "VoiceBox Shield," here is their schematic.  The main difference between the way I set up the SpeakJet and the way it is set up on Sparkfun's shield is the amplifier;  I didn't include an amplifier in my circuit yet as I was just trying to get the chip working with the minimum amount of parts, I'll show how to set up an amplifier in a later step.  Additionally, I was confused by the Jumper labeled "jumper-32-3" in the sparkfun schematic, in my circuit I just hooked digital pin 2 of the Arduino directly to pin 10 of the SpeakJet.  The circuit I set up is shown above, this schematic shown in fig 2 was modified from the original eagle files provided by Sparkfun, I've also included some photos of the breadboard setup for reference.

When you wire up the circuit and upload the code below (written by the Sparkfun folks), the SpeakJet will say "ready" then output the message "All your base are belong to us" in Robot-Speak voice followed by some R2D2-esque beeps, and light up the green LED attached to pin 16.  (Of course, you will need to hook up a speaker between pin 18 of the SpeakJet, labeled "V_OUT" in the schematic above, and GND to hear this message).  I used a small, 8Ohm speaker and only heard the message very faintly (this is why it's good to eventually amplify the output from the SpeakJet before sending it to speakers).  Press the Arduino's reset button (fig 4) to hear the message as many times as you like.

/*
Voice Box Demo Sketch
Written by Ryan Owens
SparkFun Electronics

Uses the Voice Box Shield from SparkFun to send the message "All your base are belong to us" and a series
of robot sounds to the SpeakJet chip on the shield. 

A speaker can be plugged directly into the SPK+ and - pins on the shield.

*/

//Soft serial library used to send serial commands on pin 2 instead of regular serial pin.
#include <SoftwareSerial.h>

//Define the Pin Numbers for the sketch.
#define E0  5
#define E1  6
#define E2  7
#define E3  8
#define E4  9
#define E5  10
#define E6  11
#define E7  12

#define RDY  13
#define RES  3
#define SPK  4

#define txPin  2

//Create a SoftSerial Objet
SoftwareSerial speakjet = SoftwareSerial(0, txPin);

//The message array contains the command for sounds to be sent in order to inunciate the words "All your base belong to us." Check the SpeakJet Manual for more information
//on producing words
                                                  //All              Your         Base                 Are     Belong                       to          us
char message[] = {20, 96, 21, 114, 22, 88, 23, 5, 8, 135, 8, 146, 5, 128, 153, 5, 170, 154, 8, 188, 5, 152, 5, 170, 8,128,146,8,135,8,144,5,8,191,162,5,8,134,187};

//The sounds array contains the commands to send robot sounds to the SpeakJet chip.
char sounds[] = {200, 201, 202, 203, 220, 221, 222};

void setup()  
{
  //Configure the pins for the SpeakJet module
  pinMode(txPin, OUTPUT);
  pinMode(SPK, INPUT);
  
  //Set up a serial port to talk from Arduino to the SpeakJet module on pin 3.
  speakjet.begin(9600);    
  
  //Configure the Ready pin as an input
  pinMode(RDY, INPUT);
  
  //Configure Reset line as an output
  pinMode(RES, OUTPUT);
       
  //Configure all of the Event pins as outputs from Arduino, and set them Low.
  for(int i=E0; i<=E7; i++)
  {
    pinMode(i, OUTPUT);
    digitalWrite(i, LOW);
  }
  
  //All I/O pins are configured. Reset the SpeakJet module
  digitalWrite(RES, LOW);
  delay(100);
  digitalWrite(RES, HIGH);
  
}

void loop()
{  
  //Send "All Your Base are Belong to Us" to the SpeakJet module
  speakjet.print(message);
  //Wait before sending the next string.
  delay(3000);    
  //Send the robotic sounds to the module.
  speakjet.print(sounds);
  while(1);
}

If you want to add you own messages into this code you can use the SpeakJet Dictionary as a reference.  I'll walk you through an example here.  I want to get the SpeakJet to say the phrase "Amanda is rad."  The first thing I do is construct each of the words based on the examples in the SpeakJet dictionary.  For "Amanda" we have:

man= \MM \SLOW \AY \SLOW \NE
duck= \DO \SLOW \UX \KE

Combine these to get

Amanda= \SLOW \UX \MM \SLOW \AY \SLOW \NE \DO \SLOW \UX

"is" is listed in the dictionary:

is = \SLOW \IH \ZZ

for "rad" combine the following:

rabbit=\SLOW \RR \AY \BE \RELAX \IH \TT
red = \RR \SLOW \EH \ED

to get:

rad= \SLOW \RR \AY \ED

Pages 15 and 16 of the SpeakJet User Manual gives all the numerical codes for each of these sounds.  Here is my example transcribed to numerical form:

Amanda = \SLOW \UX \MM \SLOW \AY \SLOW \NE \DO \SLOW \UX
Amanda =      8      134  140      8     132      8     141  175      8     134

is = \SLOW \IH \ZZ
is =      8     129 167

rad = \SLOW \RR \AY \ED
rad =      8     148  132 176

We can set the volume, speed, and other parameters of the speech by calling the numbers 20-23, I copied the following values from the Sparkfun code above:

20, 96, 21, 114, 22, 88, 23, 5,

this sets Volume (20) to 96, Speed (21) to 114, Pitch (22) to 88, and Bend (23) to 5.  You can play around with these numbers to learn more about how they work.  If you read the table on page 15 of the SpeakJet Manual you can find out about other control commands, as well as how to incorporate pauses into your speech. 

Putting this all together, I have the following series of numbers:

{20, 96, 21, 114, 22, 88, 23, 5, 8, 134, 140, 8, 132, 8, 141, 175, 8, 134, 8, 129, 167, 8, 148, 132, 176}

And here is the final code, it is mostly copied straight from the Sparkfun code above (I made the last "a" and "d" in "rad" slow by putting an extra 8 in front of the numbers 132 and 176 to get these parts to sound a bit more clear):

/*
"Amanda is rad"
by Amanda Ghassaei
http://www.instructables.com/id/Twitter-Enabled-Text-to-Speech/

Modified from Voice Box Demo Sketch
Written by Ryan Owens
SparkFun Electronics

*/

//Soft serial library used to send serial commands on pin 2 instead of regular serial pin.
#include <SoftwareSerial.h>

//Define the Pin Numbers for the sketch.
#define E0  5
#define E1  6
#define E2  7
#define E3  8
#define E4  9
#define E5  10
#define E6  11
#define E7  12

#define RDY  13
#define RES  3
#define SPK  4

#define txPin  2

//Create a SoftSerial Objet
SoftwareSerial speakjet = SoftwareSerial(0, txPin);

char message[] = {20, 96, 21, 114, 22, 88, 23, 5, 8, 134, 140, 8, 132, 8, 141, 175, 8, 134, 8, 129, 167, 8, 148, 8, 132, 8, 176};

void setup()  
{
  //Configure the pins for the SpeakJet module
  pinMode(txPin, OUTPUT);
  pinMode(SPK, INPUT);
  
  //Set up a serial port to talk from Arduino to the SpeakJet module on pin 3.
  speakjet.begin(9600);    
  
  //Configure the Ready pin as an input
  pinMode(RDY, INPUT);
  
  //Configure Reset line as an output
  pinMode(RES, OUTPUT);
       
  //Configure all of the Event pins as outputs from Arduino, and set them Low.
  for(int i=E0; i<=E7; i++)
  {
    pinMode(i, OUTPUT);
    digitalWrite(i, LOW);
  }
  
  //All I/O pins are configured. Reset the SpeakJet module
  digitalWrite(RES, LOW);
  delay(100);
  digitalWrite(RES, HIGH);
  
}

void loop()
{  
  delay(1000);
  speakjet.print(message);
  while(1);
}

Comments

[sudeepvnarayanan]

thanks....
am trying to do the same....
hope it works:-)

[sudeepvnarayanan]

mam,
i would like to do the same project with pic instead of arduino.
is it possible..?

[amandaghassaei]

yes, it's definitely possible, but I don't have any experience with pic sorry!

[shahrum123]

Ma'am,

Thanks for posting such an excellent project. I have a quick question. I am trying to use the system for a robot. The point is that if someone asks the robot a question, I can input the answer in the Serial port monitor of the arduino and then the robot reponds with the answer. I was wondering if the following addtion to our code would work.

void loop()
{
while (Serial.avaiable () >0) {
speakjet.println (Serial.read());
}
}

I am using your project as part of a bigger project to help the blind. If it works I will definetely share with you. Thanks.

[amandaghassaei]

the speakjet can only be used to translate text to speech, it cannot translate speech to text, is that what you are trying to do?

[shahrum123]

I am still doing text to speech but instead of putting the text in the program, I want to input the text in the serial port monitor of the arduino.

[amandaghassaei]

oh, now I understand, yes this will work.

[shahrum123]

Ma'am. The code does not work. Whenever I input something in the Serial Port monitor it does not output the text to speech conversion. Can you please help?

[amandaghassaei]

can you post your code?

[shahrum123]

I am waiting for the parts. I will let you know if it works. Thanks ma'am.

[shahrum123]

Please let me know if you need further clarification

[AntzyP]

awesome!

(crowd chants in background) video! video! video!

[Trecool771]

Amanda is rad!

[amandaghassaei]

:)

[techbitar]

Love it!

[TobaTobias]

Great project and very resoursefull! Hopefully I'll be able to do this without the ethernet shield.
Thanks!

[amandaghassaei]

cool, what are planning to use it for?

[TobaTobias]

I'd like to make a little Robot, I've been searching for weeks ways to send a tweet through arduino and processing, I checked the make it tweet guide but I couldn't find an answer because OAuth had been outdated or something changed in twitters app development. So I recently found a code from Robotgrrl with a new code for processing and it worked, so I just have to write a code for my arduino to connect with processing. Im using a PIR sensor to trigger the sketch. Hopefully I can find a cooler idea, like a robot than just a small simple PIR sensor. But for now the sensor good for tweaking. ;)

[amandaghassaei]

cool, do you have a link to the processing code?

[TobaTobias]

Sure, here it is;
http://robotgrrl.com/blog/2011/02/21/simple-processing-twitter/

[Build_it_Bob]

Way to go Amanda !! Love this !!! I still have a pile of the old radio shack IC's and always dreamed of making them talk . This looks a lot more like something I can handle.
Keep up the awesome work ! Love your style !
Build_it_Bob

[binoyxj]

Always wanted to make something like this. Thank you, Amanda.

[stringstretcher]

I love your instructables, Amanda. Keep 'em coming! We always learn something from them.

[amandaghassaei]

thanks! good to hear!

[themoose64]

This is way to complicated for me to make ( or at least right now -I havent taken a tech class yet) But this is way COOL! Nice work!

[amandaghassaei]

it's actually not too hard. If you just follow the schematics closely and copy the code that I've written, you don't really need any electronics experience to get this up and running.

[randofo]

This is some good thorough info that you have shared here Amanda.

[amandaghassaei]

thanks randy!