How to Use Arduino to Turn on a Lamp Remotely, Directly From Your IPhone/Android

Intro: How to Use Arduino to Turn on a Lamp Remotely, Directly From Your IPhone/Android

With Arduino you can really make so many fun and useful projects, especially to facilitate some tasks at home. In this article we will see how to use the Arduino to remotely turn on a lamp, or any device that is connected to the outlet of our home.
Let 's see what devices are needed to make this project:

hardware

1 x Arduino Uno cost 12 Euro, sold on Ebay
1 x ENC28J60 Ethernet card cost 5 euros, sold on Ebay
1 x Relay 220 V 10 A cost 3 Euros, sold on Ebay
1 x Ethernet cable 1 meter cost 2 Euro

software

Arduino IDE
Library for ENC28J60 https://github.com/jcw/ethercard
Sketch code lamp relay + + WebServer

STEP 1: What Is a Relay?

A relay, from the external point of view is a simple switch capable of passing current or not. This phenomenon occurs through a physical principle, based on the coupling magnet that is generated through a passage a small excitation current, which is supplied by the Arduino. There are two configurations with regard to the relay:

1. NO (Normally open)
2. NC (Normally closed)

These two configurations differ only in the code you need to write in Arduino. The first configuration, in the case of switching off the relay, no current is passed (the circuit is open) and that the lamp is turned on you need to get out of an Arduino signal "HIGH". The NC configuration is dual, in case the relay is not energized, the current flows in the device and that the lamp is off, you need to do to get out of an Arduino signal "LOW".
To recap from the point of view of the code:

NO configuration

digitalWrite(relay,LOW); // Lamp off
delay(1000);
digitalWrite(relay, HIGH); // Lamp on


Configurazione NC

digitalWrite(relay,LOW); // Lamp on
delay(1000);
digitalWrite(relay, HIGH); // Lamp off

For those who wish to learn more about how this circuit element, you can visit the website of Wikipedia, which talks about the various types of relays.

STEP 2: How to Connect the Various Cables Between Devices

The links that need to be done to make the project are quite simple. We have two devices to be connected to the Arduino: 1) the relay and 2) the Ethernet card.
Concerning the first, it will be necessary power the relay with 5 V, the ground and the pin-out, to be connected to Arduino pin set in the code, which in this case is 5.

The microcontroller Ethernet is slightly a bit 'more complicated, because they are well connected by flexible cables 6. There are two usual power cables, VCC (3.3 V, though!) And GND and 4, which are used to send and receive data over the Internet. Here is a table that summarizes the connections:

Arduino
Vcc  -> 3.3v
GND ->GND
SCK -> Pin 13
SO -> Pin 12
SI -> Pin 11
CS -> Pin 8

STEP 3: Software Installation of the Various Components

The functions that allow you to operate your ethernet card is not present in the Arduino IDE. For this reason it is necessary to install this library, inside the folder "libreries" Arduino. To do so, just download the file in. Zip, unzip it and move it to the folder of the Arduino, without opening the program. Alternatively, you can do this procedure directly from the IDE software.
Now that the library is present, we can proceed to load the file on our Arduino Uno.
To do this we download the source code from this link and press the button in the top left, to transfer it to our microcontroller. After a few seconds, if all goes well, will come the message "Loading completed." Now we can finally go to practice!

/**
Questo codice permette di accendere una lampada connessa al relè da remoto, sfruttando
la scheda di rete ENC28J60
SCK -> 13
SO -> 12
SI -> 11
CS -> 8
Vcc -> 3.3 V
GND -> GND
*/

#include <EtherCard.h>
#define RELAY_PIN 5
#define REQUEST_RATE 5000

static byte mymac[] = { 0x74,0x69,0x69,0x2D,0x30,0x31 };
char* on  = "ON";
char* off = "OFF";
boolean relayStatus;
char* relayLabel;
char* linkLabel;

byte Ethernet::buffer[700];

void setup () {
  Serial.begin(9600);
  Serial.println("Getting IP via DHCP");

  if (ether.begin(sizeof Ethernet::buffer, mymac) == 0)
    Serial.println( "Failed to access Ethernet controller");

  if (!ether.dhcpSetup())
    Serial.println("DHCP failed");

  ether.printIp("My IP: ", ether.myip);
  // ether.printIp("Netmask: ", ether.mymask);
  ether.printIp("GW IP: ", ether.gwip);
  ether.printIp("DNS IP: ", ether.dnsip);

  Serial.println();

  pinMode(RELAY_PIN, OUTPUT);
  digitalWrite(RELAY_PIN, LOW); 
  relayStatus = false;
  relayLabel = off;
  linkLabel = on;
}

void loop () {

word len = ether.packetReceive();
word pos = ether.packetLoop(len);

  if(pos) {

    if(strstr((char *)Ethernet::buffer + pos, "GET /?ON") != 0) {
      relayStatus = true;
      relayLabel = on;
      linkLabel = off;
    } else if(strstr((char *)Ethernet::buffer + pos, "GET /?OFF") != 0) {
      relayStatus = false;
      relayLabel = off;
      linkLabel = on;
    }
    digitalWrite(RELAY_PIN, relayStatus);

    BufferFiller bfill = ether.tcpOffset();
    bfill.emit_p(PSTR("HTTP/1.0 200 OK\r\n"
      "Content-Type: text/html\r\nPragma: no-cache\r\n\r\n"
      "<html><head><meta name='viewport' content='width=200px'/></head><body>"
      "<div style='position:absolute;width:200px;height:200px;top:50%;left:50%;margin:-100px 0 0 -100px'>"
      "<div style='font:bold 14px verdana;text-align:center'>Relay is $S</div>"
      "<br><div style='text-align:center'>"
      "<a href='/?$S'><img src='http://ismanettoneblog.altervista.org/blog/wp-content/uploads/2014/02/bt_$S.png'></a>"
      "<div>Controlla la lampada<div>"
      "</div></div></body></html>"
      ), relayLabel, linkLabel, linkLabel);

      ether.httpServerReply(bfill.position());
    }
  }

STEP 4: Internet of Things

The first step is to get the local ip address of the Arduino. To do this there are several possibilities: the first is to open the serial port, or the other option is to download a program to scan the host in the local network.

Now that we have the IP address, open the browser and type in our phone its address. You will see a web page like the one in the photo. 

Once you press the green button, a new page will appear, with which you can turn off the light.

To turn on the lamp, even remotely, you must open port 80, the control page of our router, choosing the corresponding IP.

STEP 5: And for Ethernet Controller W5100 ?

You can complete the project if you have the Ethernet Controller W5100. The correct code is the one in this link. http://ismanettoneblog.altervista.org/blog/lezione-14-come-accendere-lampada-remoto-arduino/

/**
Questo programma permette di accedere e spegnere una lampada da remoto
*/

#include <SPI.h>
#include <Ethernet.h>

int pinLED = 9; // pin a cui è connesso il LED
boolean acceso = false;
// Mac Address di Arduino
byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
};

// Viene inizializzata la libreria Ethernet di Arduino e il webserver gira sulla porta 80
EthernetServer server(80);

void setup() {
  pinMode(pinLED,OUTPUT);
  digitalWrite(pinLED,LOW);
  Serial.begin(9600);
  // Viene inilizzato il webserver e la connessione di rete
  Ethernet.begin(mac);
  server.begin();
  Serial.print("server is at ");
  Serial.println(Ethernet.localIP());
}

void loop() {
  // Vengono ascoltati nuovi client
  EthernetClient client = server.available();
  if (client) {
    Serial.println("new client");
    // Finisce una richiesta HTTP
    boolean currentLineIsBlank = true;
    String postText ="";
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        if(postText.length()<10){
          postText +=c;
        }
        // Se viene completato l'invio della richiesta HTTP, allora il server invia la risposta
        if (c == '\n' && currentLineIsBlank) {
          // Viene fatta una risposta HTTP, in pratica viene creata una pagina WEB in HTML
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // Dopo la risposta la connessione si interrompe
          client.println();
          client.println("<meta charset=UTF-8>"); // serve per inserire i caretteri speciali
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          client.println("<head> <TITLE>Arduino</TITLE> </head>"); // Viene creato il Titolo
          client.println("<body> <h1> Benvenuto nel Webserver Arduino </h1>"); // Viene inserito del testo
          client.println("<h3> Attraverso questa pagina è possibile accendere e spegnere lampada, connessa ad un relè </h3>");
          client.println("</body>");
          client.println("</html>");
          break;
        }
        if (c == '\n') {
          currentLineIsBlank = true;
        }
        else if (c != '\r') {
          currentLineIsBlank = false;
        }
      }
    }
    // Se l'utente ha premuto l'icona per accendere il LED
    if(postText.indexOf("?on") >0){
          digitalWrite(pinLED,HIGH);
          Serial.println("Accendi LED");
          acceso = true;
        }
     // Se l'utente ha premuto l'icona per spegnere il LED
     if(postText.indexOf("?off") >0 ){
       digitalWrite(pinLED,LOW);
        Serial.println("Spegni LED");
        acceso = false;
       }
      // Viene cambiata la pagina WEB a seconda che il LED sia spento, oppure acceso
      if(acceso){
          client.println("<a href=\"./?off\"> <img src = \"http://ismanettoneblog.altervista.org/blog/wp-content/uploads/2014/02/bt_OFF.png\"alt = \"Spegni\" ></a>");
          client.println("<h3> La lampada è accesa </h3>");
        }else{
          client.println("<a href=\"./?on\"> <img src = \"http://ismanettoneblog.altervista.org/blog/wp-content/uploads/2014/02/bt_ON.png\"alt = \"Accendi\" ></a>");
          client.println("<h3> La lampada è spenta </h3>");
          }  
    delay(1);
    // Viene chiusta la connessione
    client.stop();
    Serial.println("client disconnected");
  }
}

STEP 6: Android Application !

Now you can use your Android to control in an easy way your lamp remotely !

https://play.google.com/store/apps/details?id=com....

Comments

[MahmoudI22]

Can i make it with only one button and that one defines its state when ever i open thr application whether its now on or off?

[HarshilP14]

Does it want

SMAKN® 5V Active Low 2 Channel Relay Shield Module .
What relay voltage do i need,

[ayikb]

hello this is what i looking for my home

but can you make sketch using 2 relay moduls

[SanderJ2]

Hello, I have connected my arduino to the internet and uploaded the program but i only says "Getting IP via DHCP", after 5 minutes it was still the same how can i fix this?

[jackbell16]

May be that your router has disabled the DHCP protocol, or the ethernet cable is not well inserted in the Arduino

[SanderJ2]

I already know what it is, if you use the Arduino Mega 2560 then you need to use other pins: 50, 51, 52, 53 for the ENC28J60 and you can use the relay pin on 5

[AlvianP]

hei, very good project !

i tried your program using ENC28J60 and its working, i can turn ON/OFF remotely from my browser.
but once i try to open the IP address for my Arduino from another device (my phone), it doesnt load the page.

so i assume that this code only work for local network. (cmiiw)

how can i change it so it can work online too?

thanks in advance

[jackbell16]

The problem is that by default you can't access remotely to your router, but you need to perform an operation that is called port forwarding.
From your local network you have to open the console page of your router; move to the page of port forwarding and insert the port 80 for the TCP connection and the IP address of Arduino. Once completed this, type on google My IP address and get it. Now you can remotely switch on and off your lamp from your smartphone

[BAN PP]

Hi, can i switch a bulb/lamp or led by using remote control tell me.

thanks!

[jackbell16]

Hi,
yes you can switch on/off your lamp/led with this tutorial. The relay is able to open and close the current flow.

[eceb2]

where is the code for arduino if i want to use ENC28J60?

[Wuzi]

Hi!

How could i make it to work online, not only local?

Thanks !

[jackbell16]

The trick is use the NAT of your Router. For this purpose, you have to port forwarding the port number 80 of the IP address of Arduino. Once done this, you have to get the public IP of your broadband connection and that's all.

[MostafaE2]

can you give me example about it?

also control from PHP

thanks

[jackbell16]

Do you want to turn on and off from a PHP application your lamp?

[MostafaE2]

yes please , but online not local

i hope you can give me example

thanks

[jackbell16]

<?php

$url = 'YOUR_PUBLIC_IP';

$http = newHttpRequest($url, HttpRequest::METH_POST);

$http->addPostFields(array('value' => '?on'));

$response = $http->send();
echo$response->getBody();

?>

I've not tested it, but I think should work without any problem. Of course you have to insert your public ip of your Arduino and use the second version of the code, the one for the official ethernet shield for Arduino.

If you don't know your public ip, this is a useful web site: http://whatismyipaddress.com/. If you haven't done it, you have to open the port 80 on your router for the local ip address of Arduino, to let someone else from external, to access the Arduino.

?>

[عبداللها11]

hii >>after i get the public ip and the port >is there any changes in the code

[HarisH2]

How to use it with RN-42 bluetooth?

[jackbell16]

Why do you need to use the bluetooth technology ?