Introduction: Send Sensor Data (DHT11 & BMP180) to ThingSpeak With an Arduino, Using Cable or WiFi (ESP8266) or Use ESP8266 Alone (UPDATED AUGUST 2016)

Picture of Send Sensor Data (DHT11 & BMP180) to ThingSpeak With an Arduino, Using Cable or WiFi (ESP8266) or Use ESP8266 Alone (UPDATED AUGUST 2016)

I wrote this instructable because Thingspeak -nevermind how easy to set up- has a few hurdles that I ran into and that, judging from reactions, other people are struggling with as well.

This instructable discusses the following:

  • How to set up Thingspeak
  • How to connect your Arduino with a W5100 Ethernetshield
  • How to connect your Arduino via an ESP8266-01
  • How to connect to Thingspeak with only an ESP8266-01

NOTE: Although this presented project does work well, I would probably never combine an Arduino with an ESP8266 again because it is overkill. The ESP8266 can do a lot of things the Arduino can do, especially if it is just collecting sensor data. Have look in the 'ESP8266 only' step of this instructable, or check my newer instructables such as the one here.

Things you need:
Arduino
WS5100 EthernetShield (if you have the old ENC28J60 ethercard, look here)
Thingspeak Account
Sensors (such as DHT11 and BMP180)
Internet connection
For the WiFi:
ESP8266-01 (or other ESP8266)

I wanted to collect some weather-data with my Arduino and have that available as nice graphs, on a webpage, so I could also monitor it from afar
I could ofcourse just use an Arduino as a webserver, but if you want to do anything more than send numbers to a webpage, The Arduino will soon run out of memory.
There are services that can digest and publish your data: Pachube, later called Xively is a known one but currently they have a waiting list for their free accounts. Truthfully, I have a Pachube account that became a Xively account, but just never got any results on it.

There're few alternatives for Xively:
http://2lemetry.com

http://exosite.com

https://www.carriots.com

https://www.grovestreams.com

https://thingspeak.com

http://openenergymonitor.org

I picked 'Thingspeak'
As the signup and creating a channel etcetera is quite easy and well explained I will not go into too much detail of that. Basically after you sign up you create a channel to which you add fields where later sensors will send their data.
Under the API tab you will find an API that you later should put in your program.

I describe a simpel connection with an ethernet cable and a connection via WiFi

Step 1: Hurdles and Solutions

Picture of Hurdles and Solutions

Hurdle 1
Now where to find a program? a working example would be nice right? In the right top corner there is a button 'Support' that will go to 'Tutorials'.
Under 'Tutorials' you will find:

"Using an Arduino + Ethernet Shield to Update a ThingSpeak Channel"
Sounds great, so you download that program into your IDE, add the API -key and then compile it.
Darn.... it doesnt compile, you try to fix it (and that is certainly possible) until you come to a point you have no idea what is required.
Apparently the program still expects everybody to use the 022 or 023 IDE.
There is a link to a Github page but that will give u a program to tweet and that is not what you want, at least not for now.
Solution
You ill find a better program to start from right here:

https://github.com/iobridge/ThingSpeak-Arduino-Exa...

That program takes a reading from the A0 port and sends that to "Field1" in your datastream

Ok so you try that, you hang a variable resistor like an LDR or NTC on port A0, add your API in the program and run it.
That works fine, but I didnt only want to read a value from an Analog port, I had a DHT11 Moisture&Temperature sensor as well as a BMP180 Pressure & temperature sensor. I figured it shouldnt be too hard.

Hurdle 2
I added the necessary libraries to the Thingspeak program, added the objects and read the sensors into a variable.
The sensors however have floats as outcome and Thingspeak wants you to send strings.
With most variables it is rather easy to turn them into a string with the simple 'string' function, but it isnt that easy for floats. With floats you have to use the "dtostrf" command (which I guess stands for 'double-to-string-function'

Trying to find info on that function on internet quickly led me to endless discussions on 'how stupid' it was and people asking questions were often told "why would you need that, Serial.print will do that for you" Yeah, true, but I don't want to print, I need it because Thingspeak wants it.

Solution
To use the dtostrf command you need to set up a buffer space where the string will be stored. It works like this:

char t_buffer[10];
t=(ReadSensor);
String temp=dtostrf(t,0,5,t_buffer);

That bufferspace is important. I had it working with '7' or even '5', but when I added a second sensor that needs this function, my datastream would crash and or I got the weirdest results. I also figured that I could use the same bufferspace alternating for each sensor, but that also didnt really work, so now i have a bufferspace for each sensor.
Now I am no crack in C, so maybe there is a better way to do this, if so i would love to hear it, but this worked for me.

Hurdle3
Once I had the string conversions, I could add the data to the datastream.
The Thingspeak example program shows that for one field only, but it becomes clear pretty fast that you have to add the strings and throw in the right amount of plussesand ampersands.

Solution
So for say 4 different fields it becomes like this:

updateThingSpeak("field1="+temp+"&field2="+humid+"&field3="+pres+"&field4="+temp2);

Step 2: Connecting With Ethernetshield

Below you will find the full code.
Just a few remarks:
The BMP180 is an updated version of the BMP085. The BMP085 libraries are compatible with the BMP180.
AdaFruit has 2 versions of the libray. I picked version 1 as i found it easier to work with. Version 2 also requires installation of the 'Sensor' library.
In the code I also present an extra float: 'm'. that gives the Pressure in "mmHg" as I havent used it for now there is no string conversion yet and it is not added to the datastream, but adding it should now be as simple as 1+1

/*
Arduino --> ThingSpeak Channel via Ethernet
The ThingSpeak Client sketch is designed for the Arduino and Ethernet.
This sketch updates a channel feed with an analog input reading via the
ThingSpeak API (http://community.thingspeak.com/documentation/)
using HTTP POST. The Arduino uses DHCP and DNS for a simpler network setup.
The sketch also includes a Watchdog / Reset function to make sure the
Arduino stays connected and/or regains connectivity after a network outage.
Use the Serial Monitor on the Arduino IDE to see verbose network feedback
and ThingSpeak connectivity status.
Getting Started with ThingSpeak:
* Sign Up for New User Account - <a href="https://www.thingspeak.com/users/new" rel="nofollow"> https://www.thingspeak.com/users/new
</a>
* Enter a MAC Address in this sketch under "Local Network Settings"
* Create a new Channel by selecting Channels and then Create New Channel
* Enter the Write API Key in this sketch under "ThingSpeak Settings"
Arduino Requirements:
* Arduino with Ethernet Shield or Arduino Ethernet
* Arduino 1.0 IDE
Network Requirements:
* Ethernet port on Router
* DHCP enabled on Router
* Unique MAC Address for Arduino
Created: October 17, 2011 by Hans Scharler (http://www.iamshadowlord.com)
Additional Credits:
Example sketches from Arduino team, Ethernet by Adrian McEwen
Added dht11/BMP180 showed dtostrf function by diy_bloke 22/11/2014
*/
#include <SPI.h>
#include <Ethernet.h>
#include <dht11.h>
#include <Wire.h>
#include <Adafruit_BMP085.h> // This is the version 1 library
#define DHT11PIN 4  // The Temperature/Humidity sensor
Adafruit_BMP085 bmp;
dht11 DHT11;

// Local Network Settings
byte mac[] = { 0xD4, 0x28, 0xB2, 0xFF, 0xA0, 0xA1 }; // Must be unique on local network
// ThingSpeak Settings
char thingSpeakAddress[] = "api.thingspeak.com";
String writeAPIKey = "REPLACE_THIS_BY_YOUR_API_BUT_KEEP_THE_QUOTES";
const int updateThingSpeakInterval = 16 * 1000; // Time interval in milliseconds to update ThingSpeak (number of seconds * 1000 = interval)
// Variable Setup
long lastConnectionTime = 0;
boolean lastConnected = false;
int failedCounter = 0;
// Initialize Arduino Ethernet Client
EthernetClient client;
void setup()
{
// Start Serial for debugging on the Serial Monitor
Serial.begin(9600);
// Start Ethernet on Arduino
startEthernet();
}
void loop()
{
// Read value from Analog Input Pin 0
String analogPin0 = String(analogRead(A0), DEC);
// Print Update Response to Serial Monitor
if (client.available())
{
char c = client.read();
Serial.print(c);
}
//------DHT11--------
int chk = DHT11.read(DHT11PIN);
char t_buffer[10];
char h_buffer[10];
float t=(DHT11.temperature);
String temp=dtostrf(t,0,5,t_buffer);
//Serial.print(temp);
//Serial.print(" ");
float h=(DHT11.humidity);
String humid=dtostrf(h,0,5,h_buffer);
//Serial.println(humid);

//-----BMP180-----------
bmp.begin();
            float p=(bmp.readPressure()/100.0);//this is for pressure in hectoPascal
            float m=(bmp.readPressure()/133.3);//  this is for pressure in mmHG
            float t2=(bmp.readTemperature());
            char p_buffer[15];
            char t2_buffer[10];
            String pres=dtostrf(p,0,5,p_buffer);
            String temp2=dtostrf(t2,0,5,t2_buffer);
            Serial.println(pres);
 //         }
//----------------

// Disconnect from ThingSpeak
if (!client.connected() && lastConnected)
{
Serial.println("...disconnected");
Serial.println();
client.stop();
}
// Update ThingSpeak
if(!client.connected() && (millis() - lastConnectionTime > updateThingSpeakInterval))
{
updateThingSpeak("field1="+temp+"&field2="+humid+"&field3="+pres+"&field4="+temp2);
}
// Check if Arduino Ethernet needs to be restarted
if (failedCounter > 3 ) {startEthernet();}
lastConnected = client.connected();
}
void updateThingSpeak(String tsData)
{
if (client.connect(thingSpeakAddress, 80))
{
client.print("POST /update HTTP/1.1\n");
client.print("Host: api.thingspeak.com\n");
client.print("Connection: close\n");
client.print("X-THINGSPEAKAPIKEY: "+writeAPIKey+"\n");
client.print("Content-Type: application/x-www-form-urlencoded\n");
client.print("Content-Length: ");
client.print(tsData.length());
client.print("\n\n");
client.print(tsData);
lastConnectionTime = millis();
if (client.connected())
{
Serial.println("Connecting to ThingSpeak...");
Serial.println();
failedCounter = 0;
}
else
{
failedCounter++;
Serial.println("Connection to ThingSpeak failed ("+String(failedCounter, DEC)+")");
Serial.println();
}
}
else
{
failedCounter++;
Serial.println("Connection to ThingSpeak Failed ("+String(failedCounter, DEC)+")");
Serial.println();
lastConnectionTime = millis();
}
}
void startEthernet()
{
client.stop();
Serial.println("Connecting Arduino to network...");
Serial.println();
delay(1000);
// Connect to network amd obtain an IP address using DHCP
if (Ethernet.begin(mac) == 0)
{
Serial.println("DHCP Failed, reset Arduino to try again");
Serial.println();
}
else
{
Serial.println("Arduino connected to network using DHCP");
Serial.println();
}
delay(1000);
}

Step 3: Connect to Thingspeak Using an ESP8266 WiFi Module

Picture of Connect to Thingspeak Using an ESP8266 WiFi Module

The previous presented internet connection was made via a cable. However, there is a cheap WiFi module that is available to attach to the Arduino: The ESP 8266.
The ESP8266 is a cheap WiFi module. Bear in mind that it needs 3.3 Volt. Some models however claim to be 5 Volt tolerant. I added 2 circuits that could be used as voltage converter.
The ESP8266 really needs its own 3.3 V source as the current coming from the Arduino just doesnt cut it.
There is plenty of information on how to connect the module, I want to focus on the software to make a Thingspeak connection
The SoftSerial library is added for debugging. it is not really necessary once the progrem is working. The same goes for all the print statements to the Software serial port
I use 3 analog values rather than an example with the BMP108 and DHT11 as that requires libraries, so the implementation of theESP8266 is easier to follow. Once you get that, it is easy to implement other sensors. Just make sure you turn all output into a string
Below a program to Connect 3 analog sensors to Thingspeak via an ESP8266 module:

// <a href="https://nurdspace.nl/ESP8266" rel="nofollow">  https://nurdspace.nl/ESP8266

</a>//https://www.instructables.com/id/Using-the-ESP8266-module/
//https://www.zybuluo.com/kfihihc/note/31135
//http://tminusarduino.blogspot.nl/2014/09/experimenting-with-esp8266-5-wifi-module.html
//http://www.cse.dmu.ac.uk/~sexton/ESP8266/
//https://github.com/aabella/ESP8266-Arduino-library/blob/master/ESP8266abella/ESP8266aabella.h
//http://contractorwolf.com/esp8266-wifi-arduino-micro/
//**********************************************************
#include <SoftwareSerial.h>
int sensor_temp = A0;
int value_temp;
int sensor_light = A1;
int value_light;
int sensor_humid = A2;
int value_humid;


#define DEBUG FALSE //comment out to remove debug msgs

//*-- Hardware Serial
#define _baudrate 9600

//*-- Software Serial
//
#define _rxpin      2
#define _txpin      3
SoftwareSerial debug( _rxpin, _txpin ); // RX, TX

//*-- IoT Information
#define SSID "[YOURSSID]"
#define PASS "[YOURPASSWORD]"
#define IP "184.106.153.149" // ThingSpeak IP Address: 184.106.153.149

// GET /update?key=[THINGSPEAK_KEY]&field1=[data 1]&field2=[data 2]...;
String GET = "GET /update?key=[ThingSpeak_(Write)API_KEY]";

void setup() {
   Serial.begin( _baudrate );
  debug.begin( _baudrate );

  sendDebug("AT");
  delay(5000);
  if(Serial.find("OK"))
  {
    debug.println("RECEIVED: OK\nData ready to sent!");
    connectWiFi();
  }

}

void loop() {
  value_temp = analogRead(sensor_temp);
  value_light = analogRead(sensor_light);
  value_humid = analogRead(sensor_humid);
  String temp =String(value_temp);// turn integer to string
  String light= String(value_light);// turn integer to string
  String humid=String(value_humid);// turn integer to string
  updateTS(temp,light, humid);
  delay(3000); //
}
//----- update the  Thingspeak string with 3 values
void updateTS( String T, String L , String H)
{
  // ESP8266 Client
  String cmd = "AT+CIPSTART=\"TCP\",\"";// Setup TCP connection
  cmd += IP;
  cmd += "\",80";
  sendDebug(cmd);
  delay(2000);
  if( Serial.find( "Error" ) )
  {
    debug.print( "RECEIVED: Error\nExit1" );
    return;
  }

  cmd = GET + "&field1=" + T +"&field2="+ L + "&field3=" + H +"\r\n";
  Serial.print( "AT+CIPSEND=" );
  Serial.println( cmd.length() );
  if(Serial.find( ">" ) )
  {
    debug.print(">");
    debug.print(cmd);
    Serial.print(cmd);
  }
  else
  {
    sendDebug( "AT+CIPCLOSE" );//close TCP connection
  }
  if( Serial.find("OK") )
  {
    debug.println( "RECEIVED: OK" );
  }
  else
  {
    debug.println( "RECEIVED: Error\nExit2" );
  }
}

void sendDebug(String cmd)
{
  debug.print("SEND: ");
  debug.println(cmd);
  Serial.println(cmd);
}

boolean connectWiFi()
{
  Serial.println("AT+CWMODE=1");//WiFi STA mode - if '3' it is both client and AP
  delay(2000);
  //Connect to Router with AT+CWJAP="SSID","Password";
  // Check if connected with AT+CWJAP?
  String cmd="AT+CWJAP=\""; // Join accespoint
  cmd+=SSID;
  cmd+="\",\"";
  cmd+=PASS;
  cmd+="\"";
  sendDebug(cmd);
  delay(5000);
  if(Serial.find("OK"))
  {
    debug.println("RECEIVED: OK");
    return true;
  }
  else
  {
    debug.println("RECEIVED: Error");
    return false;
  }

  cmd = "AT+CIPMUX=0";// Set Single connection
  sendDebug( cmd );
  if( Serial.find( "Error") )
  {
    debug.print( "RECEIVED: Error" );
    return false;
  }
}



NOTE

In the latest version of the ESP8266 firmware AT+CIOBAUD is no longer supported and returns ERROR.
The replacement command is AT+IPR. See here for further details :- www.esp8266.com/viewtopic.php?f=13&t=718

More note
Apparently lately there appear to be some people experiencing difficulties because they didnt connect the ESP8266 to the hardware serial but to the software serial.
This program expects an ESP connected to hardware serial

Step 4: Using Just the ESP8266

Picture of Using Just the ESP8266

if you come upon this page and see gibberish... there was a full step here, but somehow Instructables decided it would be better to replace it with gibberish...after i already saved it. I will give it another go In the previous step I used an ESP8266 to send the sensorvalues that were read by an Arduino to Thingspeak. However, it is also possible to do it without an Arduino at all. I connected a DHT11 to pin 2 of my ESP8266-01 and used the following program. I can't take full credit for the program, I think the original is from Jeroen Beemster

#include <DHT.h> //  DHT.h library
#include <ESP8266WiFi.h> // ESP8266WiFi.h library

#define DHTPIN 2
#define DHTTYPE  DHT11

const char* ssid     = "YourNetworkSSID";
const char* password = "YourPassword";
const char* host = "api.thingspeak.com";
const char* writeAPIKey = "YourWriteAPI";

DHT dht(DHTPIN, DHTTYPE, 15);

void setup() {
  // Initialize sensor
 dht.begin();
  delay(1000);

//  Connect to WiFi network
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
  }
}

void loop() {
 float humidity = dht.readHumidity();
 float temperature = dht.readTemperature();

  if (isnan(humidity) || isnan(temperature)) {
    return;
  }

// make TCP connections
  WiFiClient client;
  const int httpPort = 80;
  if (!client.connect(host, httpPort)) {
    return;
  }

  String url = "/update?key=";
  url+=writeAPIKey;
  url+="&field1=";
  url+=String(temperature);
  url+="&field2=";
  url+=String(humidity);
  url+="\r\n";
  
  // Request to the server
  client.print(String("GET ") + url + " HTTP/1.1\r\n" +
               "Host: " + host + "\r\n" + 
               "Connection: close\r\n\r\n");
    delay(1000);
}

It is not the goal of this instructable to explain how to program the ESP8266, there are plenty of sources for that. A good one is here. If you already have an USB-TTL module at 3.3 Volt, you dont need to worry about voltages. If you only have a 5Volt USB-TTL module you still can use it but have to use a voltage divider between the Tx of the module and the Rx of the ESP8266. Never ever put 5 volt on the ESP8266

Note: The DHT library from Adafruit contains an error that usually doesnt occur when using an Arduino, but can become apparent when using an ESP8266, especially if the program is a bit bigger. See the enclosed picture for changes you need to make in the cpp file. It basically is commenting out two lines

Step 5: A Bonus

In case you do not want to use Thingspeak but just want your own webserver: use this program:

/* 
 * DHT11 Sensor connected to Pin 2
 <a href="http://arduino-info.wikispaces.com/ethernet-temp-humidity" rel="nofollow">  http://arduino-info.wikispaces.com/ethernet-temp-...>
 Based on code by David A. Mellis & Tom Igoe
Adapted by diy_bloke
 * bmp180sensor on a4/a5

 */
/*-----( Import needed libraries )-----*/
#include <SPI.h>
#include <Ethernet.h>
#include <dht11.h>
#include <Wire.h>
//#include <Adafruit_Sensor.h>
//#include <Adafruit_BMP085_U.h>
#include <Adafruit_BMP085.h>
/*-----( Declare Constants and Pin Numbers )-----*/
#define DHT11PIN 2  // The Temperature/Humidity sensor

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };

/*-----( Declare objects )-----*/
IPAddress ip(192,168,1, 177);

// Initialize the Ethernet server library
// with the IP address and port you want to use
// (port 80 is default for HTTP):
EthernetServer server(80);

//Adafruit_BMP085_Unified bmp = Adafruit_BMP085_Unified(10085);
Adafruit_BMP085 bmp;
dht11 DHT11;  //The Sensor Object
/*-----( Declare Variables )-----*/

void setup()   /****** SETUP: RUNS ONCE ******/
{
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
  }

  // start the Ethernet connection and the server:
  Ethernet.begin(mac, ip);
  server.begin();
  Serial.print(F("server is at "));
  Serial.println(Ethernet.localIP());
}//--(end setup )---

void loop()   /*----( LOOP: RUNS OVER AND OVER AGAIN )----*/
{
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    Serial.println(F("new client"));
    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connnection: close");
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          // add a meta refresh tag, so the browser pulls again every 5 seconds:
          client.println("<meta http-equiv=\"refresh\" content=\"5\">");
          client.println("<head>");
          client.println("<title>");
          client.println(F("My Home Environment"));
          client.println("</title>");
          client.println("</head>");
          client.println("<body>");
          client.print(F("<h3>My Home Environment</h3>"));
          //client.println("<br />");

          /*----(Get sensor reading, calculate and print results )-----------------*/

          int chk = DHT11.read(DHT11PIN);

          Serial.print(F("Read sensor: "));
          switch (chk)
          {
          case 0:
            Serial.println(F("OK"));
            break;
          case -1:
            Serial.println(F("Checksum error"));
            break;
          case -2:
            Serial.println(F("Time out error"));
            break;
          default:
            Serial.println(F("Unknown error"));
            break;
          }
          /* Get a new sensor (BMP085) event */
          // sensors_event_t event;
          // bmp.getEvent(&event);
          //--------------
          client.print(F("<table style='border:1px solid black; background-color: white;'>"));
          client.print(F("<tr><td>"));
          client.print("<font color='red'>Temperature</font> (°C): ");
          client.print(F("</td><td align='right'>"));
          client.println((float)DHT11.temperature, 1);
          client.println(F("<br />"));
          client.print(F("</td></tr>"));
          client.print(F("<tr><td>"));
          client.print("<b>Temperature</b> (°F): ");
          client.print(F("</td><td align='right'>"));
          client.println(Fahrenheit(DHT11.temperature), 1);
          client.println("<br />");
          client.print(F("</td></tr>"));
          client.print(F("<tr><td>"));
          client.print("<font color='blue'>Humidity</font> (%): ");
          client.print(F("</td><td align='right'>"));
          client.println((float)DHT11.humidity, 0);
          client.println("<br />");
          client.print(F("</td></tr>"));
          client.print(F("<tr><td>"));
          /*
          client.print("<b>Temperature</b> (°K): ");
           client.println(Kelvin(DHT11.temperature), 1);
           client.println("<br />");
           */
          client.print("<i>Dew Point</i> (°C): ");
          client.print(F("</td><td align='right'>"));
          client.println(dewPoint(DHT11.temperature, DHT11.humidity));
          client.println("<br />");
          client.print(F("</td></tr>"));
          client.print(F("<tr><td>"));
          client.print("<i>Dew PointFast</i> (°C): ");
          client.print(F("</td><td align='right'>"));
          client.println(dewPointFast(DHT11.temperature, DHT11.humidity));
          client.println("<br />");
          client.print(F("</td></tr>"));
          client.print(F("<tr><td>"));

          if (!bmp.begin()) {
            client.print("geen sensor");
          }
          else
          {
            client.print("Pressure (hPa): ");
            client.print(F("</td><td align='right'>"));
            client.println(bmp.readPressure()/100.0);
            client.print(F("</td></tr>"));
            client.print(F("<tr><td>"));
            client.print("Pressure (mmHg): ");
            client.print(F("</td><td align='right'>"));
            client.println(bmp.readPressure()/133.3);
            client.print(F("</td></tr>"));
            client.print(F("<tr><td>"));
            client.println("Temperature (°C): ");
            client.print(F("</td><td align='right'>"));
            client.print(bmp.readTemperature());
            client.println("<br />");
          }
          client.print(F("</td></tr>"));
          client.print(F("</table>"));
          /* Display the results (barometric pressure is measure in hPa) */

          /* Display atmospheric pressure in hPa */
          /*    client.print("Pressure: ");
           client.println(event.pressure);
           client.println(" hPa");
           client.println("<br />");
           */


          /*--------( End Sensor Read )--------------------------------*/
          client.println("</body>");
          client.println("</html>");
          break;
        }
        if (c== '\n'){
          // you're starting a new line
          currentLineIsBlank = true;
        }
        else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
    Serial.println(F("client disonnected"));
  }
} // END Loop

/*-----( Declare User-written Functions )-----*/
//
//Celsius to Fahrenheit conversion
double Fahrenheit(double celsius)
{
  return 1.8 * celsius + 32;
}

//Celsius to Kelvin conversion
double Kelvin(double celsius)
{
  return celsius + 273.15;
}

// dewPoint function NOAA
// reference: <a href="http://wahiduddin.net/calc/density_algorithms.htm" rel="nofollow">  http://arduino-info.wikispaces.com/ethernet-temp-...>
double dewPoint(double celsius, double humidity)
{
  double A0= 373.15/(273.15 + celsius);
  double SUM = -7.90298 * (A0-1);
  SUM += 5.02808 * log10(A0);
  SUM += -1.3816e-7 * (pow(10, (11.344*(1-1/A0)))-1) ;
  SUM += 8.1328e-3 * (pow(10,(-3.49149*(A0-1)))-1) ;
  SUM += log10(1013.246);
  double VP = pow(10, SUM-3) * humidity;
  double T = log(VP/0.61078);   // temp var
  return (241.88 * T) / (17.558-T);
}

// delta max = 0.6544 wrt dewPoint()
// 5x faster than dewPoint()
// reference: <a href="http://en.wikipedia.org/wiki/Dew_point" rel="nofollow">  http://arduino-info.wikispaces.com/ethernet-temp-...>
double dewPointFast(double celsius, double humidity)
{
  double a = 17.271;
  double b = 237.7;
  double temp = (a * celsius) / (b + celsius) + log(humidity/100);
  double Td = (b * temp) / (a - temp);
  return Td;
}
/* ( THE END ) */



Comments

ErikA45 (author)2017-09-23

Hi, re the ethernet code compilation error: the cause is the absence of the DHT11 and BMP085 modules. Is it possible to write code for a simple analog input to be read and transmitted? Thanks!

diy_bloke (author)ErikA452017-09-24

yes, that is very well possible, take out the DHT11 and BMP code and do an analogread.

I must say though that I have no idea what platform you are using now. An Arduino with ethernetshield? Or just a nodeMCU?

ErikA45 (author)diy_bloke2017-09-28

I would use here an Arduino Uno with ethernet shield. How can a NodeMCU be used with ethernet?

diy_bloke (author)ErikA452017-09-28

a NodeMCU board connects via WiFi

ErikA45 (author)diy_bloke2017-09-28

ok, but that is in step 3 (with wifi). I was refering to step 2: Arduino with ethernet shield.

diy_bloke (author)ErikA452017-09-28

I am not referring to any step, just saying the NodeMCU connecs through wifi,not through ethernet, if you also want to connect the NodeMCU through ethernet -though i do not dee the point of that- you need to connect e.g. a wiz5100 module

ErikA45 (author)diy_bloke2017-09-24

For this trial I loaded the wifi code in an Arduino Uno. Now I just have to figure out the sketch for use with analog inputs instead of the sensor modules. Will take some time but I will report back.

diy_bloke (author)ErikA452017-09-25

I have a code for analog inpiuts in one of the steps

ErikA45 (author)diy_bloke2017-09-25

I found that now in step 3; compiles perfect. Just need to test with Thingspeak now.

I read you would now program ESP8266 for all this instead of combining with Arduino. Can you give some url's where I can find more beginners' info on that please?

ErikA45 (author)2017-09-28

Hi, I notice you set the hardware serial baudrate to 9600baud. But the ESP8266 does by default communicate with 11520baud. Now do you get it to work at 9600baud?

diy_bloke (author)ErikA452017-09-28

just set it at 9600 Bd in the IDE
But I am getting confused, you just wrote that you are using a UNO with ethernet shield

ErikA45 (author)diy_bloke2017-09-28

well, you have 2 programs, one that runs with Uno and Ethernet shield. And the other with Uno and ESP8266: that is what I am referring to here; the ESP8266 is by default set to communicate at 115200 baud (if you use a fairly recent firmware version).

diy_bloke (author)ErikA452017-09-28

Just one further remark Erik, I already said I think that I do not use the ESP8266 anymore just to connect an arduino via WiFi. At the time of the ESP8266-01 when there was hardly a core available, that seemed the best thing to do, but the ESP8266 has been developed further. Anyway, you know that and there might be many reasons why you still want to do it.
yet, i have never been fond of the AT commands, and the soft serial solution another way to do it is if you want to use an Arduino and still have WiFi is to connect them with I2C. You can just let the Arduino do its thing and put values in a register and the ESP82666 can just pick them up and send them over WiFi.
You could choose either one as slave or as master, depending on your configuration and needs.

ErikA45 (author)diy_bloke2017-09-28

Hi, to me thisis just for learning purposes, later I will use the applications as you refer to.

I did not even know you can connect ESP8266 over I2C. Interesting!

diy_bloke (author)ErikA452017-09-28

ah ok. In that case you cant set the baudrate via de IDE. When I made this the default was 9600 I think. It is something you have to set with the AT commands, but if your ESP is 115200 it might be handier to just set it in the program as 115200

ErikA45 (author)2017-09-22

Can the wireless sketch be used with a Node MCU 1.0 development board? I get a compiler error stating 'A1' was not declared in this scope.

diy_bloke (author)ErikA452017-09-24

Not sure which 'wireless' sketch you refer to. You mean the one in Step3?

Step 3 is about an Arduino connected to an ESP8266-01 module, wher would you want to use the nodeMCU? to replace the Arduino? That would be extremely odd. or to replace the 8266-01? that would be total overkill.
Or just to replace both? The code is totally unsuitable for that as it is about the AT driven communication between the 2 modules.
Note that this is a relatively old instructable and now I wouldnt dream of using an arduino in combo with an ESP, I would just use an ESP8266 as stand alone.

The reason that A1 is not declared in this scope is because the NodeMCU does not have an A1, it only has one analogport A0

ErikA45 (author)diy_bloke2017-09-24

Hi, thank you for your reply. I had wrongly loaded the wifi sketch into the ESP module. I know better now.

ErikA45 (author)2017-09-22

Loading the ethernet code in an Arduino Uno gives a general compiler error: exit status 1: what do I do wrong?

diy_bloke (author)ErikA452017-09-24

that is really too little information to know what is going on. If you set 'verbose output' in your preferences the error becomes more clear

OscarC24 made it! (author)2017-06-25

Hi! i improved my last code so it can be batery powered!

https://thingspeak.com/channels/88430

by serial com :

despertando

....................

Humedad: 57.00%

Tempratura: 25.00°

Luz: 77

GET /update?key=**********************&field1=25.00&field2=57.00&field3=77

HTTP/1.1

durmiendo

rl

diy_bloke (author)OscarC242017-06-29

thanks for sharing. I see you use a bare esp-12. From a battery point of view that is a good choice

diy_bloke (author)OscarC242017-06-27

great, thank you for sharing

mariaaDum12 (author)2017-06-04

Hello,

so I want to use step 3 from posting data to my own server. Can u tell me what exactylu I have to change ? I changed the ip addres and for get i used /write_data.php?data1=value1. But it didn't seem to work. Thanks a lot!

diy_bloke (author)mariaaDum122017-06-04

Maria, I am not sure what server you haveand forgive me if i maybe misundersyand your question but usually posting data to another server involves more than just changing the ip address.

The data may come in, but your server probably has no idea what to do with it. So exactly what are you trying to do and what server are u using

himanshu6611 (author)2017-04-07

Hi diy_bloke

I tried your code with the **exact specifications** as you gave, but it didn't seem to go well. I wired up my arduino to Esp and then i started getting this text all the time on the serial monitor. Can't figure out how to proceed further.... Your help would be really appreciated on this!

AT+CIPSTART="TCP","184.106.153.149",80

AT+CIPSEND=67

AT+CIPCLOSE

What could be the problem? I tried different power supplies, a solo power supply of 3v3 (actually it gave out 3.24) and then from the USB2Serial Converter (that was also a stable 3v3, i had tried it earlier on my esp and the IDE showed a successful flash).

P.S. Using arduino+esp is mandatory, else it is easy to do it with esp alone like you mentioned numerous times already in this instructable.

Thanks

diy_bloke (author)himanshu66112017-04-09

Sorry to hear that. The 3.24 Volt should not be the problem.
Sadly though this project has been quite a while ago for me so I am a bit rusty on the AT commoands. I presume you are sure you connected the ESP to the right port and dont have Rx+Tx switched (I doubt you have but make sure).
Also you are using the right WiFi credentials?

faridfauzi (author)2017-03-18

is it possible for me to send text message to thingspeak web server?

diy_bloke (author)faridfauzi2017-03-20

what you send to theThingspeakserver is ascii text, but as far as I know it needs to be a cipher in ascii,as in the end it all goes in a graph presentation

SonuG6 (author)2016-11-10

1)Hi can u please give the connection diagram,using arduino uno esp8266 and 3 analog values?(so as to counter check whether my connection diagram is right?

2) Is this where i put my channel key?Have i put it correctly?

String GET = "[ABBAVJ339FYK1ZZ]";

diy_bloke (author)SonuG62017-01-02

indeed that is where you put the api key.
Having said that, nowadays it is a bit of a waste to combine an ESP8266 with a Nano, as the ESP8266 can be used on its own

diy_bloke (author)SonuG62016-11-14

the connection between arduino and esp8266 is always TX-RX and RX-TX
the channel key should not have brackets around it.
In al honesty, it nowadays is a bit of a waste to use en Arduino in combo with an ESP8266 as the ESP8266 can do it alone and in fact it is easier to program as well. Now you may think ẅhat about analog values on the ESP8266? add a cheap ADC module (less than a dollar). Look here a few lines of code and you are ready to go

SonuG11 (author)diy_bloke2016-12-05

Thankyou diy_bloke..

1)But my doubt is if I am using Hardware serial for esp8266, how does communication with serial monitor happen through pins 2 and 3?Because by default communication with serial monitor is with rx and tx pins right?

2) I have already used arduino uno in one of my projects,thats y I am hanging on to it.I can just addon esp code to it..

3)Also when I am separately checking with just serial monitor ,ESP module is sending and receiving ,but with this setup,module is not responding.What do u think could be the problem?

Thanking you,

diy_bloke (author)SonuG112016-12-05

where I say "try this code" the wrong link got inserted. Should be this one

https://github.com/volca/cactus_micro_trial/blob/m...
But again, I have some doubts on that code

SonuG11 (author)diy_bloke2016-12-09

Also will u plz tell how does the data flow happen with debug.print?

diy_bloke (author)SonuG112016-12-05

It has been a while, but as far as I recall I had the ESP on the hardware serial. The communication with the Serial monitor over pins 2 and 3 is through the softwareserial library.
Now if you look at the program you see that you can switch the debug (i.e. what is being sent to the Software Serial) on and off. That is so that when it is all werking, you do not need that part of the code anymore.

What you see in your 'Serial Monitor' depends on what port you choose. So suppose you would not connect the ESP8266 and connect an USB cable to the Arduino and subsequently look in your serial monitor, you would see what is being sent to the ESP8266, If you would connect your computer to the software serial port (e.g. with an FTDI) you would see what your arduino prints as debug messages (a long as your debug is true).
Also, you see the commandline

if(Serial.find( ">" ) )

This also indicates that it is the regular serialport that the ESP8266 is connected to as you need to look for that return string in th ebuffer between the ESP8266 and the Arduino. It is the sign the ESP8266 comes back with a message, not the Arduino

As I found and find communication with the ESP8266 via AT commands rather cumbersome and as the ESP8266 is a microcontroller in itself, I have given up on combining it with an arduino but I understand your reason why.
Now one of the problems in having yr arduino comunicate with an ESP8266 is baudrate, in the early days supposedly there wereesp8266 modules that had different baudrates. Try change that.
Also, make sure not to feed the ESP8266 from yr arduino, it needs a decent psu preferably with somewhat of a buffer capacitor

If you do not have an ftdi handy, remove yr esp8266 and attach a usb cable to the standard serial port and see what commando's are being sent.

You said that if you "normally check' the esp with yr serial monitor... can I presume that you then have it connected to an FTDI cable? What speed are you using?

Although it can happen that maybe Instructables corrupts the code, I copied it from instructables again and compiled and run it, that did fine (although I didnt have an esp connected to it). Nevertheless, it could be that somewhere a mistake slipt in so I'd say try this code. Mind you though that it is using different software serial pins. AND as far as I can see is using the software serial for ESP8266 comunication and I cannot garantee that code is actually working.

Also, you will find some problems connecting to an ESP8266 discussed here.


SonuG11 (author)diy_bloke2016-12-08

Thankyou diy_bloke..

1)I have powered esp8266 using lm317 and its getting 3.6V, not from arduino.But ground of arduino and esp is same.

2) Baud rate in serial monitor and program is 115200.

3)DEBUG is true as

#define DEBUG true

4) Your comment on different COM ports was really helpful. When

computer is connected to the software serial port (with an FTDI) ,serial monitor output is as in fig2.At times that Com port didnot get detected.When the ESP8266 is not connected and an USB cable to the Arduino was connected ,subsequent serial monitor output is fig 1.That is I find serial.print and sendDebug function is working but not debug.print.

can i see both com ports together?I guess not.

However i tried following connectoion

computer -ftdi cable( rx >tx(software arduino ),tx>rx(software arduino)) AND USB cable-arduino(hardware rx>tx esp,harware tx>rx esp)

5)Also found that Serial.find is not working.

6) When i said i normally checked esp with serial monitor,I did the the following.

a) Loaded bare minimum sketch in arduino.

b) connected tx>tx and rx>rx of arduino and esp.

c) sent at commands manually and it was receiving and sending fine at baud rate 115200.

Thanking you,

sedski (author)2017-01-01

Hello,

Can you kindly confirm where to put the api key. This is how I tried to use it, but the data wasn't sent. To simplify things, I am not reading data from sensors. I just put some static values to see if they go through.

Using Arduino Nano and ESP8266-01

value_temp = 22; //analogRead(sensor_temp);
value_light = 0;//analogRead(sensor_light);
value_humid = 30;//analogRead(sensor_humid);

Please confirm the lines below. I didn't modify the commented line, but part of my key is in the second line.

// GET /update?key=[THINGSPEAK_KEY]&field1=[data 1]&field2=[data 2]...;

String GET = "GET /update?key=9W8Z902N4YE";

NerdBishop (author)2016-11-17

Thanks for the tutorial, was very helpful. i spent lot of hours
trying to fix the DHT.cpp ERROR till i came accros this and it really
help. Thanks once again

diy_bloke (author)NerdBishop2016-11-17

Good. I hope it is of some comfort that I also lost hours on that error :-)

Be careful updating your libraries, I think the error is still present

PierceS2 (author)2016-11-16

Hey great tutorial thank you! I have difficulty sending the program from IDE to the arduino (i am using the arduino uno and a 8266 with two analog sensors). The program only uploads when I disconnect the Rx pin on the arduino (which is connected to the TX pin on the ESP). Without this connection, the program info isn't sent to things speak. Any suggestions? Also, will the program you posted connect to the ESP even after I have programmed the ESP to connect atuomatically to my phone's hotspot.

diy_bloke (author)PierceS22016-11-17

Pierce, let me start with yr last question. If you programmed any program in your esp, the AT instruction set is gone.

With regard to yr 1st question: indeed you cannot upload anything to your arduino if you have something else attached to the serialport. It is not the intention to keep uploading the program. You upload it once.to be able to connect the esp8266 and being able to debug the program defines a software serialport as well.

Having said this. Currently i would not attach an arduino to an esp8266 anymore as the esp can usually handle it alone

cristi.constantin (author)2016-10-27

Hey man, nice tutorial, but it should be split into separate projects, because it's very long and complex and confusing.

Great work!

Tnx, maybe i could split it in different projects, but I thought make it a one stop place for Thingspeak. I will see if maybe I can clarify the different sections a bit more

MohammedS153 (author)2016-10-14

hello can anyone help!!! , i want to upload water sensor data to thingspeak,I connected my ESP8266 with arduino uno, and took this code and made a little changes on it to serve my goal.

however no matter what i do the serial monitor gives these repeated lines:
AT+CIPSTART="TCP","184.106.153.149",80

AT+CIPSEND=52

AT+CIPCLOSE

I should mention that i didn't update the ESP8266 firmware, and its still with the same setting as i bought it, the power also is supplied from the arduino 3.3v pin, i know i should make a separate power supply, but i checked the voltage and it reads 3.3 at all pins.

this is my modified code:

#include <SoftwareSerial.h>

int sensor_water = A0;

int value_water;

#define DEBUG FALSE //comment out to remove debug msgs

//*-- Hardware Serial

#define _baudrate 9600

//*-- Software Serial

//

#define _rxpin 2

#define _txpin 3

SoftwareSerial debug( _rxpin, _txpin ); // RX, TX

//*-- IoT Information

#define SSID "[waterfirst]"

#define PASS "[waterfirst]"

#define IP "184.106.153.149" // ThingSpeak IP Address: 184.106.153.149

// GET /update?key=[THINGSPEAK_KEY]&field1=[data 1]&field2=[data 2]...;

String GET = "GET /update?key=fghdhgdfhgdfahadh&field1=0";

void setup() {

Serial.begin( _baudrate );

debug.begin( _baudrate );

sendDebug("AT");

delay(5000);

if(Serial.find("OK"))

{

debug.println("RECEIVED: OK\nData ready to sent!");

connectWiFi();

}

}

void loop() {

value_water = analogRead(sensor_water);

String water =String(value_water);// turn integer to string

updateTS(water);

delay(3000); //

}

//----- update the Thingspeak string with 1 value

void updateTS( String W)

{

// ESP8266 Client

String cmd = "AT+CIPSTART=\"TCP\",\"";// Setup TCP connection

cmd += IP;

cmd += "\",80";

sendDebug(cmd);

delay(2000);

if( Serial.find( "Error" ) )

{

debug.print( "RECEIVED: Error\nExit1" );

return;

}

cmd = GET + "&field1=" + W +"\r\n";

Serial.print( "AT+CIPSEND=" );

Serial.println( cmd.length() );

if(Serial.find( ">" ) )

{

debug.print(">");

debug.print(cmd);

Serial.print(cmd);

}

else

{

sendDebug( "AT+CIPCLOSE" );//close TCP connection

}

if( Serial.find("OK") )

{

debug.println( "RECEIVED: OK" );

}

else

{

debug.println( "RECEIVED: Error\nExit2" );

}

}

void sendDebug(String cmd)

{

debug.print("SEND: ");

debug.println(cmd);

Serial.println(cmd);

}

boolean connectWiFi()

{

Serial.println("AT+CWMODE=1");//WiFi STA mode - if '3' it is both client and AP

delay(2000);

//Connect to Router with AT+CWJAP="SSID","Password";

// Check if connected with AT+CWJAP?

String cmd="AT+CWJAP=\""; // Join accespoint

cmd+=SSID;

cmd+="\",\"";

cmd+=PASS;

cmd+="\"";

sendDebug(cmd);

delay(5000);

if(Serial.find("OK"))

{

debug.println("RECEIVED: OK");

return true;

}

else

{

debug.println("RECEIVED: Error");

return false;

}

cmd = "AT+CIPMUX=0";// Set Single connection

sendDebug( cmd );

if( Serial.find( "Error") )

{

debug.print( "RECEIVED: Error" );

return false;

}

}

diy_bloke (author)MohammedS1532016-10-14

which ESP8266 model?

MohammedS153 (author)diy_bloke2016-10-14

ESP8266-01 black

diy_bloke (author)MohammedS1532016-10-15

before anything else, I strongly advise trying to feed it from a proper psu. Most of these problems are from an insufficient psu. that it still measures 3.3 does not mean that much, as the esp8266 may experience short drops as it starts sending... and then reset itself

MohammedS153 (author)diy_bloke2016-10-19

I am really stuck with powering the ESP8266, till the point i think i burned the chip it self, is there any way to know if its still working or not.

I tried powering it from a regulator with a 3.3V and intensity up to 500mA, i tried voltage divider circuit and nothing, nothing is working.
the only thing i can do is send these commands
AT

AT+RST

AT+GMR

i think i managed to update its firmware as i get new version when i send this command AT+GMR, but rather than that nothing.

i see a lot of pages saying use (logic level shifter, use voltage regulator, use FTDI.... but i don't know i tried too many things and its not working).

About This Instructable

192,980views

195favorites

License:

Bio: I am a physician by trade. After a career in the pharmeceutical world I decided to take it a bit slower and do things I ... More »
More by diy_bloke:Working With the Funduino W5100 Ethernet Module.Uploading Data to ThingSpeak With MQTTAdding an MCP23017 I/O Extender to Arduino or ESP8266
Add instructable to: